Teensy 2019: nRF24L01 test sending a data struct

From the Arduino sketchbook (was GettingStarted_HandlingData).

2019-teensy-nrf24/tests/teensy_nrf24_struct_test/teensy_nrf24_struct_test.ino

@@ -0,0 +1,179 @@
+
+/*
+  Getting Started example sketch for nRF24L01+ radios
+  This is an example of how to send data from one node to another using data structures
+  Updated: Dec 2014 by TMRh20
+*/
+
+#include <SPI.h>
+#include "RF24.h"
+
+byte addresses[][6] = {"1Node", "2Node"};
+
+
+/****************** User Config ***************************/
+/***      Set this radio as radio number 0 or 1         ***/
+//bool radioNumber = 0;
+bool radioNumber = 1;
+
+/* Hardware configuration: Set up nRF24L01 radio on SPI bus plus pins 7 & 8 */
+//RF24 radio(9, 10); // CE, CSN
+RF24 radio(39, 15);
+/**********************************************************/
+
+
+// Used to control whether this node is sending or receiving
+bool role = 0;
+
+/**
+  Create a data structure for transmitting and receiving data
+  This allows many variables to be easily sent and received in a single transmission
+  See http://www.cplusplus.com/doc/tutorial/structures/
+*/
+struct dataStruct {
+  unsigned long _micros;
+  float value;
+  float value2;
+  float value3;
+} myData;
+
+void setup() {
+    SPI.setSCK(14);
+    SPI.setMOSI(11);
+    SPI.setMISO(12);
+
+  while (!Serial) ; // wait for arduino serial monitor
+
+  Serial.begin(115200);
+  Serial.println(F("RF24/examples/GettingStarted_HandlingData"));
+  Serial.println(F("*** PRESS 'T' to begin transmitting to the other node"));
+
+  radio.begin();
+
+  // Set the PA Level low to prevent power supply related issues since this is a
+  // getting_started sketch, and the likelihood of close proximity of the devices. RF24_PA_MAX is default.
+  radio.setPALevel(RF24_PA_LOW);
+
+  // Open a writing and reading pipe on each radio, with opposite addresses
+  if (radioNumber) {
+    radio.openWritingPipe(addresses[1]);
+    radio.openReadingPipe(1, addresses[0]);
+  } else {
+    radio.openWritingPipe(addresses[0]);
+    radio.openReadingPipe(1, addresses[1]);
+  }
+
+  myData.value = 1.22;
+  myData.value2 = 1.22;
+  myData.value3 = 1.22;
+  // Start the radio listening for data
+  radio.startListening();
+}
+
+
+
+
+void loop() {
+
+
+  /****************** Ping Out Role ***************************/
+  if (role == 1)  {
+
+    radio.stopListening();                                    // First, stop listening so we can talk.
+
+
+    Serial.println(F("Now sending"));
+
+    myData._micros = micros();
+    myData.value2 = myData.value*2;
+    myData.value3 = myData.value*3;
+    if (!radio.write( &myData, sizeof(myData) )) {
+      Serial.println(F("failed"));
+    }
+
+    radio.startListening();                                    // Now, continue listening
+
+    unsigned long started_waiting_at = micros();               // Set up a timeout period, get the current microseconds
+    boolean timeout = false;                                   // Set up a variable to indicate if a response was received or not
+
+    while ( ! radio.available() ) {                            // While nothing is received
+      if (micros() - started_waiting_at > 200000 ) {           // If waited longer than 200ms, indicate timeout and exit while loop
+        timeout = true;
+        break;
+      }
+    }
+
+    if ( timeout ) {                                            // Describe the results
+      Serial.println(F("Failed, response timed out."));
+    } else {
+      // Grab the response, compare, and send to debugging spew
+      myData.value2=0;
+      myData.value3=0;
+      radio.read( &myData, sizeof(myData) );
+      unsigned long time = micros();
+
+      // Spew it
+      Serial.print(F("Sent "));
+      Serial.print(time);
+      Serial.print(F(", Got response "));
+      Serial.print(myData._micros);
+      Serial.print(F(", Round-trip delay "));
+      Serial.print(time - myData._micros);
+      Serial.print(F(" microseconds Value "));
+      Serial.print(myData.value);
+      Serial.print(F(" Value "));
+      Serial.print(myData.value2);
+      Serial.print(F(" Value "));
+      Serial.println(myData.value3);
+    }
+
+    // Try again 1s later
+    delay(100);
+  }
+
+
+
+  /****************** Pong Back Role ***************************/
+
+  if ( role == 0 )
+  {
+
+    if ( radio.available()) {
+      // Variable for the received timestamp
+      while (radio.available()) {                          // While there is data ready
+        radio.read( &myData, sizeof(myData) );             // Get the payload
+      }
+
+      radio.stopListening();                               // First, stop listening so we can talk
+      myData.value += 0.01;                                // Increment the float value
+      radio.write( &myData, sizeof(myData) );              // Send the final one back.
+      radio.startListening();                              // Now, resume listening so we catch the next packets.
+      Serial.print(F("Sent response "));
+      Serial.print(myData._micros);
+      Serial.print(F(" : "));
+      Serial.println(myData.value);
+    }
+  }
+
+
+
+
+  /****************** Change Roles via Serial Commands ***************************/
+
+  if ( Serial.available() )
+  {
+    char c = toupper(Serial.read());
+    if ( c == 'T' && role == 0 ) {
+      Serial.print(F("*** CHANGING TO TRANSMIT ROLE -- PRESS 'R' TO SWITCH BACK"));
+      role = 1;                  // Become the primary transmitter (ping out)
+
+    } else if ( c == 'R' && role == 1 ) {
+      Serial.println(F("*** CHANGING TO RECEIVE ROLE -- PRESS 'T' TO SWITCH BACK"));
+      role = 0;                // Become the primary receiver (pong back)
+      radio.startListening();
+
+    }
+  }
+
+
+} // Loop